Introducing the New Way to Shop from Home/Iceland.iso/pc/internetaccess.dir/00316_Script_Jump to Marker Button

Text File | 2003-03-05 | 14KB | 395 lines

-- DESCRIPTION --

on getBehaviorDescription me
  return \
    "JUMP TO MARKER BUTTON" & RETURN & RETURN & \
    "A click on the sprite makes the playback head jump to a chosen marker in the same movie. " & \
    "You can choose between the previous marker, the next marker, or any named marker in the movie." & RETURN & RETURN & \
    "If more than one marker has the same name as the chosen marker, the playback head will jump to the first marker with that name in the movie. " & \
    "If you need to use duplicate names, try adding a different number of spaces at the end of each, so that they appear the same but are in fact different." & RETURN & RETURN & \
    "This behavior is designed for use with the Jump Back Button. " & \
    "You can set it to record the frame number of the current marker so that the Jump Back Button can subsequently return. " & \
    "Note: This feature relies on a global variable: gNavigationButtonList." & RETURN & RETURN & \
    "Use the Jump to Movie Button behavior to jump to a marker in a different movie." & RETURN & RETURN & \
    "PERMITTED MEMBER TYPES:" & RETURN & \
    "Graphic members" & RETURN & RETURN & \
    "PARAMETERS:" & RETURN & \
    "* Jump to marker in this movie" & RETURN & \
    "* 'Go to' or 'Play and return'?" & RETURN & \
    "* Remember current marker for Back button" & RETURN & RETURN & \
    "Select Remember Current Marker for Back Button to ensure that the behavior 'remembers' which markers have already been visited." & RETURN & RETURN & \
    "Use the associated Jump Back Button behavior on a separate sprite to return to visited markers in reverse order." & RETURN & RETURN & \
    "ASSOCIATED BEHAVIORS:" & RETURN & \
    "* Jump to Movie button" & RETURN & \
    "* Jump Back Button" & RETURN & \
    "* Jump Forward Button" & RETURN & \
    "* Push Button (to alter rollover / mouseDown states)"
end getBehaviorDescription


on getBehaviorTooltip me
  return \
    "Use with graphic members." & RETURN & RETURN & \
    "When you drop this behavior on a sprite, you can choose which marker in the current movie to jump to on mouseUp. " & \
    "You can also choose to jump to the next or the previous marker." & RETURN & RETURN & \
    "Use this behavior with the Jump Back Button to allow the user to return to visited sequences."
end getBehaviorTooltip



-- NOTES FOR DEVELOPERS --

-- The main handler is Jump, which is triggered by mouseUp.  The Initiialize
-- handler runs a series of error-checks.  These will alert designers
-- in any of the following cases:
-- * if the chosen marker has been deleted or renamed
-- * if more than one marker has the same name as the chosen marker
-- * if the global gNavigationButtonList does not have a valid structure

-- USE OF 'BACK/FORWARD BUTTON' BEHAVIORS
--
-- This behavior is designed to be use in collaboration with 'Jump Back' and
-- 'Jump Forward' buttons so that users can retrace their steps.
--
-- Information about what markers have already been visited is stored in a
-- global variable: gNavigationButtonList.  As a global, this variable is
-- available to all navigation behaviors, on any sprite in any movie.
--
-- gNavigationButtonList has the following structure:
--   [#stack [...], #index: [...], #forward: [...]]
-- Each of the subLists has the structure:
--   [[#frame: <integer>, #movie: <movieName>], [...]]
--
-- #index is not currently exploited.  It provides a list of all markers
-- visited, in the order of their first visit.  It could be used to create
-- a pop-up menu, or to check if a player had visited a particular scene.
--
-- Information concerning the most recently visited marker is stored in the
-- last item of the #stack list.  This item is copied to a local variable,
-- then removed from the #stack.  Information concerning the current marker
-- is appended to the #forward list, so that users can subsequently retrace
-- their steps.



-- HISTORY --

-- 10 September 1998: written for the D7 Behaviors Palette by James Newton
-- 22 October 1998:   "play"/"go to" added, error-checking eased to allow
--                     authors to use the behavior before creating markers.
--  5 January   2000: updated to D8 <Kraig Mentor>
--  14 February 2000: Added resolve handler. Added markerList conversion to
--                    GDPL hander.



-- PROPERTIES --

-- author-defined parameters:
property myMarker
property myJumpMode
property myReturn

global gNavigationButtonList -- Only declared if it is to be used


-- EVENT HANDLERS --

on beginSprite me
  resolve(me)
  Initialize me
end beginSprite

on mouseUp me
  Jump me
end prepareFrame


-- CUSTOM HANDLERS --

on resolve me
  --This handler is used to convert non-English languages to Lingo terms.
  case myMarker of
    "next":
      myMarker = #next
    "loop":
      myMarker = #loop
    "previous":
      myMarker = #previous
  end case
end on


on Initialize me -- sent BY beginSprite
  -- Error checking: Marker name
  if not getPos ([#next, #previous, #loop], myMarker) then
    -- Does myMarker still exist?
    theMarkerList = RETURN&the labelList
    markerExists = offset (RETURN&myMarker&RETURN, theMarkerList)
    if not markerExists then
      ErrorAlert me, #markerMissing, myMarker
    else
      -- Is myMarker still unique?
      delete char 1 to markerExists of theMarkerList
      if offset (RETURN&myMarker&RETURN, theMarkerList) then
        ErrorAlert me, #runtime_DuplicateMarkers, myMarker
      end if
    end if
  end if

  -- Error checking: Global variable
  if myReturn then
    global gNavigationButtonList -- Only declared if it is to be used

    if voidP (gNavigationButtonList) then
      -- Initialize gNavigationButtonList
      gNavigationButtonList = [#stack: [], #forward: [], #index: []]
    else -- Is it the right global?
      if gNavigationButtonList.ilk <> #propList then
        ErrorAlert (me, #invalidGlobal, gNavigationButtonList)
      else if not gNavigationButtonList.findPos(#stack) then
        ErrorAlert (me, #invalidGlobal, gNavigationButtonList)
      else if not gNavigationButtonList.findPos(#index) then
        ErrorAlert (me, #invalidGlobal, gNavigationButtonList)
      else if not gNavigationButtonList.findPos(#forward) then
        ErrorAlert (me, #invalidGlobal, gNavigationButtonList)
      end if
    end if
  end if
  -- End of error checking
end Initialize


on Jump me -- sent by mouseUp
  case myMarker of
    #previous:targetIsNewMarker = (marker (-the maxInteger / 2) <> marker (0))
    #loop:    targetIsNewMarker = FALSE
    #next:    targetIsNewMarker = (marker (0) <> marker (the maxInteger / 2))
    otherwise
      targetIsNewMarker = (marker (0) <> marker (myMarker))
  end case

  if myReturn and targetIsNewMarker then
    -- Remember where to come back to
    global gNavigationButtonList -- Only declared if it is to be used

    currentMarker = [#frame: marker (0), #movie: the movieName]
    -- Add currentMarker to #stack
    gNavigationButtonList.stack.append(currentMarker)
    -- Check if currentMarker is already in #index
    if not gNavigationButtonList.index.getPos(currentMarker) then
      gNavigationButtonList.index.append(currentMarker)
    end if
    -- Empty #forward list
    gNavigationButtonList.forward = []
  end if

  -- Go to frame indicated by myMarker
  if myJumpMode  = "Go to" then
    case myMarker of
      #previous: go previous
      #loop:     go loop
      #next:     go next
      otherwise
        go marker (myMarker)
    end case
  else -- play => play done
    case myMarker of
      #previous: play marker (-1)
      #loop:     play marker (0)
      #next:     play marker (1)
      otherwise:
        play myMarker
    end case
  end if
end Jump


on substituteStrings(me, parentString, childStringList) --------------
  -- Sent by errorAlert
  --
  -- * Modifies parentString so that the strings which appear as
  --   properties in childStringList are replaced by the values
  --   associated with those properties.
  --
  -- <childStringList> has the format ["^1": "replacement string"]
  --------------------------------------------------------------------

  i = childStringList.count()
  repeat while i
    tempString = ""
    dummyString  = childStringList.getPropAt(i)
    replacement  = childStringList[i]
    lengthAdjust = dummyString.char.count - 1
    repeat while TRUE
      position = offset(dummyString, parentString)
      if not position then
        parentString = tempString&parentString
        exit repeat
      else
        if position <> 1 then
          tempString = tempString&parentString.char[1..position - 1]
        end if
        tempString = tempString&replacement
        delete parentString.char[1..position + lengthAdjust]
      end if
    end repeat
    i = i - 1
  end repeat

  return parentString
end substituteStrings



-- ERROR CHECKING --

on ErrorAlert me, theError, data
  -- Send by getPropertyDescriptionList, initialize
  -- Determine the behavior's name
  behaviorName = string (me)
  delete word 1 of behaviorName
  delete the last word of behaviorName
  delete the last word of behaviorName
  -- Convert #data to useful value
  case data.ilk of
    #void: data = "<void>"
    #symbol: data = "#"&data
  end case

  case theError of

    #getPDL_DuplicateMarkers:
      tError1 = "Two or more markers in this movie have the same name. " & \
    " This could lead to " & RETURN & \
    "confusion if you use this behavior to go to a named marker."
      tError2 = "Duplicate marker(s) = ^0"
      tError2 = substituteStrings(me, tError2, ["^0":data])
      alert(tError1 & RETURN & RETURN & tError2)

    #markerMissing:
      if the runMode = "Author" then
        tError1 = "BEHAVIOR ERROR: Frame ^0, Sprite ^1"
        tError1 = substituteStrings(me, tError1, ["^0":the frame, "^1": the currentSpriteNum])
        tError2 = "Behavior ^0"
        tError2 = substituteStrings(me, tError2, ["^0": behaviorName])
        tError3 = "The chosen marker no longer exists." & RETURN & \
    "Choose a valid marker in the Behavior Parmeters dialog."
        tError4 = "Current marker = ^0"
        tError4 = substituteStrings(me, tError4, ["^0": data])
        alert(tError1 & RETURN & RETURN & tError2 & RETURN & RETURN & tError3 & RETURN & RETURN & tError4)
      end if
      abort

    #runtime_DuplicateMarkers:
      if the runMode = "Author" then
        tError1 = "BEHAVIOR ERROR: Frame ^0, Sprite ^1"
        tError1 = substituteStrings(me, tError1, ["^0":the frame, "^1": the currentSpriteNum])
        tError2 = "Behavior ^0"
        tError2 = substituteStrings(me, tError2, ["^0": behaviorName])
        tError3 = "The chosen marker does not  have a unique name. " & \
    " The playback head will jump to the first marker with this name:"
        tError4 = "Duplicate marker name = ^0"
        tError4 = substituteStrings(me, tError4, ["^0": data])
        alert(tError1 & RETURN & RETURN & tError2 & RETURN & RETURN & tError3 & RETURN & RETURN & tError4)
      end if

    #invalidGlobal:
      tError1 = "BEHAVIOR ERROR: Frame ^0, Sprite ^1"
      tError1 = substituteStrings(me, tError1, ["^0":the frame, "^1": the currentSpriteNum])
      tError2 = "Behavior ^0"
      tError2 = substituteStrings(me, tError2, ["^0": behaviorName])
      tError3 = "[#stack [...], #index: [...], #forward: [...]]"
      tError4 = "Current value = ^0"
      tError4 =  substituteStrings(me, tError4, ["^0": data])
      alert(tError1 & RETURN & RETURN & tError2 & RETURN & RETURN & tError3 & RETURN & RETURN & tError4)
      halt
  end case
end ErrorAlert





on isOKToAttach (me, aSpriteType, aSpriteNum)

  tIsOK = 0
  if aSpriteType = #graphic then
    tIsOK = 1
  end if

  return(tIsOK)
end on


-- AUTHOR-DEFINED PARAMETERS --

on getPropertyDescriptionList me

  currentMember = sprite(the currentSpriteNum).member

  markersList = GetMarkers (me)
  if markersList.count() = 2 then -- [[<markers>], [<duplicates>]]
    ErrorAlert (me, #getPDL_DuplicateMarkers, markersList[2])
  end if

  tLabelList = []
  tLabelList.add("next")
  tLabelList.add("loop")
  tLabelList.add("previous")

  repeat with i = 1 to count(the markerList)
    tLabelList.add((the markerList).getProp((the markerList).getPropAt(i)))
  end repeat

  return \
[ \
 #myMarker: \
 [ \
  #comment: "On mouseUp, jump to marker", \
  #format: #string, \
  #range: tLabelList,\
  #default: "next"\
 ], \
 #myJumpMode: \
 [ \
  #comment: "Jump Mode", \
  #format:  #string, \
  #range:  ["Go to", "Play and Return"], \
  #default: "Go to" \
 ], \
 #myReturn: \
 [ \
  #comment: "Remember current marker for Back button?", \
  #format:  #boolean, \
  #default:  TRUE \
 ] \
]
end getPropertyDescriptionList


on GetMarkers me -- Sent by getPropertyDescriptionList
  localMarkerList = []
  duplicatesList = []
  markerString = the labelList
  delete the last char of markerString
  markerCount = the number of lines of markerString
  repeat with i = 1 to markerCount
    theMarker = markerString.line [i]
    if localMarkerList.getPos(theMarker) then
      -- Duplicate marker name
      if not duplicatesList.getPos(theMarker) then
        duplicatesList.append(theMarker)
      end if
    else
      localMarkerList.append(theMarker)
    end if
  end repeat
  if duplicatesList.count() then
    return [localMarkerList, duplicatesList]
  else
    return [localMarkerList]
  end if
end GetMarkers